# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>

_gemname='sqlite3'
pkgname="ruby-${_gemname}"
pkgver=2.9.3
pkgrel=1
pkgdesc='Ruby bindings for the SQLite3 embedded database'
url='https://github.com/luislavena/sqlite3-ruby'
arch=('x86_64' 'aarch64')
license=('BSD-3-Clause')
options=('!emptydirs')
depends=(
  ruby
  ruby-mini_portile2
  sqlcipher
  sqlite
)
makedepends=(
  ruby-bundler
  ruby-rake
  ruby-rake-compiler
  ruby-rake-compiler-dock
  ruby-rdoc
)
checkdepends=(
  ruby-minitest
)
source=("https://github.com/sparklemotion/sqlite3-ruby/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
sha512sums=('1141e19c823f786f46f947451ac27cf36c5f3409f0d0e2bf6cde519e3b47d65c23c65bdd354c7ae315434226bdb7f9868c06298119f6af7a4715250ea886d6b0')
b2sums=('164a3254b7dd3af7c9cf921391dd53356704f7a0844cdf2a503ce1d3fae5414d36fafb0e157186f36665582afafaad3253816cb69260d47d7645bd6c9e1895ce')

prepare() {
  cd "${_gemname}-ruby-${pkgver}"

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed --in-place --regexp-extended \
    --expression 's|~>|>=|g' \
    "${_gemname}.gemspec"

  # remove rubocop
  rm --verbose rakelib/format.rake

  sed --in-place --regexp-extended \
    --expression 's|:rubocop, ||g' \
    Rakefile

  sed --in-place --regexp-extended \
    --expression '/rubocop/d' \
    Gemfile
}

build() {
  cd "${_gemname}-ruby-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  rake compile -- --enable-system-libraries --with-sqlcipher
  rake build

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --build-root "tmp_install" \
    "pkg/${_gemname}-${pkgver}.gem"
}

check() {
  cd "${_gemname}-ruby-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install${_gemdir}" rake test
}

package() {
  cd "${_gemname}-ruby-${pkgver}"

  cp --archive --verbose tmp_install/* "${pkgdir}"

  install --verbose -D --mode=0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: ts=2 sw=2 et:
