# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Maintainer: Caleb Maclennan <caleb@alerque.com>

pkgname=python-puremagic
pkgver=2.1.1
pkgrel=1
pkgdesc="A Python module that will identify a file based off it's magic numbers"
arch=(any)
url='https://github.com/cdgriffith/puremagic'
license=(MIT)
depends=(python)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools
  python-setuptools-scm
  python-wheel
)
checkdepends=(python-pytest)
source=("$pkgname::git+$url#tag=$pkgver")
sha512sums=('26057e5d5e7c46f72d4b0b3562edf6a21e76c4d0c6194bb7886536b36b9ff7bec93204f6a549f6b209ef210bbc06c099f030148eb6ae76aa3db4dcb9ab6fd544')
b2sums=('9ae21b1a1e000c00b39a36f7e2f70f1945905a96d69b458335da1af4bcff8ad5a80c523e1c8b4cfa4c827154b2ff64857daa056f1d1d3a2b49ea99490dc3c303')

build() {
  cd "$pkgname"

  python -m build --wheel --no-isolation
}

check() {
  cd "$pkgname"

  PYTHONPATH="$PWD:$PYTHONPATH" pytest -v
}

package() {
  cd "$pkgname"

  python -m installer --destdir="$pkgdir" dist/*.whl

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
