# Maintainer: Carl Smedstad <carsme@archlinux.org>

pkgname=python-msgspec
pkgver=0.21.1
pkgrel=1
pkgdesc='A fast serialization and validation library, with builtin support for JSON, MessagePack, YAML, and TOML'
arch=(x86_64 aarch64)
url=https://github.com/jcrist/msgspec
license=(BSD-3-Clause)
depends=(
  glibc
  python
  python-attrs
  python-typing_extensions
)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools
  python-setuptools-scm
  python-wheel
)
checkdepends=(
  python-msgpack
  python-pytest
)
optdepends=(
  'python-tomli-w: for TOML writing support'
  'python-yaml: for YAML support'
)
source=("$pkgname::git+$url.git#tag=$pkgver")
b2sums=('8df0228126f6fc5a8e0954e3b59513304096111d3906a29fdef7eb04a3f10c8ead935181204fcf4e5a8a0bdd463df19c0d8eaa9c6fffac89a0674cf09d0e8f14')

build() {
  cd $pkgname
  python -m build --wheel --no-isolation
}

check() {
  cd $pkgname
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m pytest tests/unit
}

package() {
  cd $pkgname
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
}
