# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>

_name=imagesize_py
pkgname=python-imagesize
pkgver=2.0.0
pkgrel=1
pkgdesc='Analyzes JPEG/JPEG 2000/PNG/GIF/TIFF/SVG/Netpbm/WebP image headers and returns image size or DPI'
url=https://github.com/shibukawa/imagesize_py
arch=(any)
license=(MIT)
depends=(python)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools
  python-wheel
)
source=("git+$url.git#tag=$pkgver")
b2sums=('96d547c9c9850c86dc141f1036d427dd766f24b6958b64c1e6fce1d1ccda2ea28a6ec4b5dcd06dcbe9c7d5f32159a761f4b354540fd09adfc60cc7f0d19c5f92')

build() {
  cd $_name
  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd $_name
  python -m unittest discover -v
}

package() {
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  install -d "$pkgdir"/usr/share/licenses/$pkgname
  ln -s "$site_packages"/imagesize-$pkgver.dist-info/licenses/LICENSE.rst \
    "$pkgdir"/usr/share/licenses/$pkgname

  cd $_name
  python -m installer --destdir="$pkgdir" dist/*.whl
}
