# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgbase=lib32-gdk-pixbuf2
pkgname=(
  lib32-gdk-pixbuf2
)
pkgver=2.42.11
pkgrel=2
pkgdesc="An image loading library (32-bit)"
url="https://wiki.gnome.org/Projects/GdkPixbuf"
arch=(x86_64)
license=(LGPL-2.0-or-later)
depends=(
  gdk-pixbuf2
  lib32-glib2
  lib32-glibc
  lib32-libjpeg
  lib32-libpng
  lib32-libtiff
  shared-mime-info
)
makedepends=(
  git
  meson
)
optdepends=(
  "lib32-librsvg: Load .svg, .svgz, and .svg.gz"
)
source=(
  "git+https://gitlab.gnome.org/GNOME/gdk-pixbuf.git#tag=$pkgver"
  gdk-pixbuf-query-loaders-32.hook
  0001-fix-build-failure-due-to-typo-in-the-build-script.patch
)
b2sums=('23af2f9f3cd542e6d6d14203a8037400df1e22e89884bddfc1439195e5c788ceec532a7bdda2c1685bb2355ea1303484872b836fdb6827cd448b57c36e6786a6'
        '0b432bdeb31acdd66c8a861551cabf4f83efd3c441614dbb64b7ac11fdbb97c76412b5706bb18ff1ed890de0a4c51bf02bb531eb4693e6d68021b5372cb5897a'
        '16e5b72b2a50c1c733a1688c2ff6b55b6a920530bacc28e8e60dfe62c0b40c875611186c4962b2d183ef2e3ab26ea0a5108f3bbe20c1059fef0dbf4f16891f23')

prepare() {
  cd gdk-pixbuf

  # https://gitlab.archlinux.org/archlinux/packaging/packages/gdk-pixbuf2/-/issues/1
  # https://gitlab.gnome.org/GNOME/gdk-pixbuf/-/merge_requests/165
  git apply -3 ../0001-fix-build-failure-due-to-typo-in-the-build-script.patch
}

build() {
  local meson_options=(
    --cross-file lib32
    -D builtin_loaders=all
    -D gtk_doc=false
    -D installed_tests=false
    -D introspection=disabled
    -D man=false
    -D others=enabled
  )

  arch-meson gdk-pixbuf build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  provides=(libgdk_pixbuf-2.0.so)
  install=lib32-gdk-pixbuf2.install

  meson install -C build --destdir "$pkgdir"

  rm -rf "$pkgdir"/usr/{include,lib,share}
  find "$pkgdir/usr/bin" -type f -not -name gdk-pixbuf-query-loaders -delete
  mv "$pkgdir"/usr/bin/gdk-pixbuf-query-loaders{,-32}

  install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
}

# vim:set sw=2 sts=-1 et:
