# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Anatol Pomozov <anatol@archlinux.org>

pkgname=virglrenderer
pkgver=1.3.0
pkgrel=2
pkgdesc="A virtual 3D GPU library, that allows the guest operating system to use the host GPU to accelerate 3D rendering"
url="https://virgil3d.github.io/"
arch=(x86_64 aarch64)
license=(MIT)
depends=(
  glibc
  libdrm
  libepoxy
  libgcc
  libsysprof-capture
  libva
  libx11
  mesa
)
makedepends=(
  check
  git
  meson
  ninja
  python
  python-yaml
  vulkan-headers
)
source=(
  "git+https://gitlab.freedesktop.org/virgl/virglrenderer.git#tag=$pkgver"
)
b2sums=('9bf19968ccc1bbe3814f0d2d15200e9846c11f285cca490f4c207ae4ffa79234e9458984fd06058d17ab193f201185877bddceadf152947f141b138af52e1a45')

build() {
  # shellcheck disable=SC2054
  local meson_options=(
    -D drm-renderers=amdgpu-experimental,panfrost-experimental,asahi,msm,i915-experimental
    -D tests=true
    -D tracing=sysprof
    -D venus=true
    -D video=true
  )

  arch-meson $pkgname build "${meson_options[@]}"
  meson compile -C build
}

check() {
  VRENDTEST_USE_EGL_SURFACELESS=1 meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
  install -Dm644 $pkgname/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}

# vim:set sw=2 sts=-1 et:
