# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Marcin (CTRL) Wieczorek <marcin@marcin.co>
# Contributor: Xiao-Long Chen <chenxiaolong@cxl.epac.to>

pkgname=umockdev
pkgver=0.19.7
pkgrel=1
pkgdesc="Record/mock hardware devices for bug reports and regression tests"
arch=('x86_64' 'aarch64')
url="https://github.com/martinpitt/umockdev/"
license=('LGPL-2.1-or-later')
depends=('systemd' 'libgudev' 'libpcap')
makedepends=('meson' 'gobject-introspection' 'gtk-doc' 'vala')
source=(https://github.com/martinpitt/umockdev/releases/download/$pkgver/$pkgname-$pkgver.tar.xz
        open_tree_eperm.patch)
sha256sums=('c8f72e151913bc0e94c575f8f12109082f72392442b28ed8ea47a0a379210870'
            'SKIP')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i "${srcdir}/open_tree_eperm.patch"
}

build() {
  cd $pkgname-$pkgver

  arch-meson -Dgtk_doc=true ../build
  ninja -v -C ../build
}

check() {
  cd $pkgname-$pkgver

  meson test -C ../build --print-errorlogs
}

package() {
  cd $pkgname-$pkgver

  DESTDIR="${pkgdir}" meson install -C ../build
}
