# Maintainer: Anatol Pomozov
# Contributor: Michael Lass <bevan@bi-co.net>
# Contributor: Philipp Schrader <philipp.schrader+arch@gmail.com>

pkgname=uboot-tools
pkgver=2026.04
pkgrel=1
pkgdesc='U-Boot bootloader utility tools'
arch=(x86_64 aarch64)
url='https://www.denx.de/wiki/U-Boot/WebHome'
license=("GPL-2.0-or-later AND BSD-3-Clause AND BSD-2-Clause AND LGPL-2.1-or-later AND LGPL-2.0-or-later")
depends=(openssl)
makedepends=(python python-setuptools swig)
source=(https://ftp.denx.de/pub/u-boot/u-boot-$pkgver.tar.bz2{,.sig})
validpgpkeys=('F3CEA8743D60E0192F9B4C7A2BE2A0F50ABFE40A')
options=(!lto)
sha1sums=('d224fb78fb42d901645dd49a3036a74e37c408d3'
          'SKIP')
sha256sums=('ac7c04b8b7004923b00a4e5d6699c5df4d21233bac9fda690d8cfbc209fff2fd'
            'SKIP')

build() {
  cd u-boot-$pkgver
  make tools-only_defconfig
  make tools-all KBUILD_HOSTLDFLAGS=${LDFLAGS}
}

package() {
  install -m 755 -d "$pkgdir"/usr/bin
  install -m 755 -t "$pkgdir"/usr/bin/ u-boot-$pkgver/tools/{mk{,env}image,env/fw_printenv,img2srec,dumpimage,netconsole,jtagconsole,ncb,kwboot}
  ln -s fw_printenv "$pkgdir"/usr/bin/fw_setenv
  install -m 644 -Dt "$pkgdir"/usr/share/man/man1/ u-boot-$pkgver/doc/{mkimage,dumpimage,kwboot}.1
}
