# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Fabian Bornschein <fabiscafe@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Alexander Fehr <pizzapunk gmail com>

pkgbase=tinysparql
pkgname=(
  tinysparql
  tinysparql-docs
)
pkgver=3.11.1
pkgrel=1
pkgdesc="Low-footprint RDF triple store with SPARQL 1.1 interface"
url="https://tinysparql.org/"
arch=(x86_64 aarch64)
license=(GPL-2.0-or-later)
depends=(
  avahi
  glib2
  glibc
  icu
  json-glib
  libgcc
  libsoup3
  libstemmer
  libxml2
  sqlite
)
makedepends=(
  asciidoc
  bash-completion
  dbus
  gi-docgen
  git
  glib2-devel
  gobject-introspection
  meson
  python-dbus
  python-gobject
  python-tappy
  systemd
  vala
)
checkdepends=(man-db)
source=("git+https://gitlab.gnome.org/GNOME/tinysparql.git#tag=${pkgver/[a-z]/.&}")
b2sums=('f4cf14773dbd12abfe2794190798e77fdcc5182e4093851c9cb7e3ae282b27572629f9462b30c7474bbf2d71a7434337141869fc1d85fd774ee5e7ed071a7ede')

prepare() {
  cd $pkgname
}

build() {
  local meson_options=(
    -D tests_tap_protocol=true
  )

  arch-meson tinysparql build "${meson_options[@]}"
  meson compile -C build
}

check() {
  dbus-run-session meson test -C build --print-errorlogs -t 3 ||:
}

package_tinysparql() {
  provides=(
    "tracker3=$pkgver"
    libtinysparql-3.0.so
  )
  replaces=('tracker3<=3.7.3-2')
  conflicts=('tracker3<=3.7.3-2')

  meson install -C build --destdir "$pkgdir"

  mkdir -p docs/usr/share
  mv {"$pkgdir",docs}/usr/share/doc
}

package_tinysparql-docs() {
  pkgdesc+=" (documentation)"
  depends=()
  mv docs/* "$pkgdir"
}

# vim:set sw=2 sts=-1 et:
