# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Stephen Brown II <Stephen [dot] Brown2 [at] gmail.com>

pkgname=stoken
pkgver=0.92
pkgrel=6
pkgdesc='RSA SecurID-compatible software token for Linux/UNIX systems'
url='https://github.com/cernekee/stoken'
arch=('x86_64' 'aarch64')
license=('LGPL-2.1-or-later')
depends=('nettle' 'libxml2')
makedepends=('gtk3')
optdepends=('gtk3: required for stoken-gui')
provides=('libstoken.so')
source=(https://downloads.sourceforge.net/stoken/${pkgname}-${pkgver}.tar.gz{,.asc}
        https://github.com/stoken-dev/stoken/commit/8fc6f0dd.patch
        nettle-4.patch
        82.patch)
sha256sums=('aa2b481b058e4caf068f7e747a2dcf5772bcbf278a4f89bc9efcbf82bcc9ef5a'
            'SKIP'
            'dc1bfc755a3b2b368398a4623817b4093840469b6fb45be65d53754c4a6042f7'
            'ac2e4a9506c9e70b4c200ad1d56799fdb36f15a7bf474b492939ca9f5d7e693c'
            'SKIP')
validpgpkeys=('45DFF2D5205FE8CD74C2EE6C63B81599BC0B0D65')

prepare() {
  cd ${pkgname}-${pkgver}
# Fix build with nettle 4
  patch -p1 -i ../8fc6f0dd.patch
  patch -p1 -i ../nettle-4.patch
  patch -p1 -i ../82.patch
  autoreconf -fiv
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make -k check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 CHANGES -t "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: ts=2 sw=2 et:
