# Maintainer: Carl Smedstad <carsme@archlinux.org>

pkgname=rebar3
pkgver=3.27.0
pkgrel=2
pkgdesc="Erlang build tool that makes it easy to compile and test Erlang applications and releases"
arch=('any')
url="https://github.com/erlang/rebar3"
license=('Apache-2.0')
depends=(
  erlang-common_test
  erlang-core
  erlang-dialyzer
  erlang-edoc
  erlang-erl_interface
  erlang-eunit
  erlang-parsetools
)
makedepends=(git)
source=(
  "git+$url.git#tag=$pkgver"
  "$pkgname-otp29-compat.patch"
)
b2sums=('9198659cd4bce693ede6c00e68077236d55d6a04f95fa00308e49e28f296e454dd2b4469b88aabcecd3c5c8fcb95a68bef7b3d94e2a7bd93139a08aa3c0d88b4'
        'fd18fdf3565141a7fcd9a6748dbf45a1bec8ca7f47cfc77b3f76d1061716fd08827554cf50a3eab731d1668e4c3571b235a7f60346607ecd768c17cb8c2ae760')

prepare() {
  cd $pkgname
  patch -Np1 < ../$pkgname-otp29-compat.patch
}

build() {
  cd $pkgname
  ./bootstrap
}

check() {
  cd $pkgname
  ./rebar3 ct
}

package() {
  cd $pkgname
  install -vDm755 -t "$pkgdir/usr/bin" rebar3
  install -vDm644 -t "$pkgdir/usr/lib/erlang/lib/rebar-$pkgver/ebin" \
    _build/bootstrap/lib/rebar/ebin/*.beam \
    _build/bootstrap/lib/rebar/ebin/rebar.app

  install -vDm644 -t "$pkgdir/usr/share/bash-completion/completions" \
    apps/rebar/priv/shell-completion/bash/rebar3
  install -vDm644 -t "$pkgdir/usr/share/zsh/site-functions" \
    apps/rebar/priv/shell-completion/zsh/_rebar3
  install -vDm644 -t "$pkgdir/usr/share/fish/vendor_completions.d" \
    apps/rebar/priv/shell-completion/fish/rebar3.fish

  install -vDm644 -t "$pkgdir/usr/share/man/man1" manpages/rebar3.1
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" \
    README.md rebar.config.sample THANKS
}
