# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: nut543 <kfs1@online.no>
# Contributor: Dale Blount <dale@archlinux.org>

pkgname=re2c
pkgver=4.5.1
pkgrel=1
arch=(x86_64 aarch64)
pkgdesc='A tool for generating C-based recognizers from regular expressions'
url='https://re2c.org'
license=(LicenseRef-re2c)
depends=(
  glibc
  libgcc
  libstdc++
)
makedepends=(
  cmake
  python
)
source=("https://github.com/skvadrik/re2c/archive/$pkgver/re2c-$pkgver.tar.gz")
b2sums=('0c054c4ad3e694a7784d8076e807a07f41c2315ba369fff8080911015b25e53c1164a2e8513d17be4a40e36eecb3d9de02fea377134a65ec206c67b691389ec8')

build() {
  # CMAKE_BUILD_TYPE=None explicitly disallowed in cmake/Re2cBuildType.cmake
  cmake -S $pkgname-$pkgver -B build \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Wno-dev
  cmake --build build
}

check() {
  ctest --test-dir build --output-on-failure
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  cd $pkgname-$pkgver
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
