# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor:  Chris Severance aur.severach aATt spamgourmet dott com

pkgname=python-pathspec
_name=${pkgname#python-}
pkgver=1.1.1
pkgrel=1
pkgdesc='Utility library for gitignore style pattern matching of file paths'
arch=('any')
url=https://github.com/cpburnz/python-pathspec
license=('MPL-2.0')
depends=('python')
makedepends=(
  'git'
  'python-build'
  'python-flit-core'
  'python-installer'
  'python-wheel'
)
optdepends=(
  'python-google-re2: re2 backend'
)
source=("git+$url.git#tag=v$pkgver")
b2sums=('f241c1db613c03a48764db57fd5da435e9a0a525a2c90e6ed85ca3e1ce7cfe8aafcb900a6041512d9050a5210e7b2818fbd003d1b047aeb35aa214f7fd15e782')

build() {
  cd $pkgname
  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd $pkgname
  python -m unittest
}

package() {
  cd $pkgname
  python -m installer --destdir="$pkgdir" dist/*.whl

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
