# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Florian Pritz <bluewind@xinu.at>

pkgname=python-ansi2html
pkgver=1.9.2
pkgrel=4
pkgdesc='Convert text with ANSI colour codes to HTML'
arch=(any)
url='https://github.com/pycontribs/ansi2html'
license=(LGPL-3.0-or-later)
depends=(python)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools
  python-setuptools-scm
  python-wheel
)
checkdepends=(python-pytest)
source=("$pkgname::git+$url#tag=v$pkgver")
sha512sums=('dcbfbffc71325052d49653156fea91ca0392199297cd782b0eb6f19e5d01b0b66ff95dd102d2298e7620d2466246ad6ffe17ebf5b28117541110918192569cf5')
b2sums=('80eed29ebf734a122e5ec41b7d400ed444bf1beb1c37d42b83a91b65cf58975d008313775441c241b2a235c6ce6dd1461143b81c357d1e42e0fbd9efd940e5d9')

prepare() {
  cd "$pkgname"

  # fix: replace deprecated pkg_resources
  # https://github.com/pycontribs/ansi2html/pull/258
  git cherry-pick --no-commit 9c5ed6c803d7c0481af8f5fa67573509930c7930
}

build() {
  cd "$pkgname"

  SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver python -m build --wheel --no-isolation
}

check() {
  cd "$pkgname"

  # temporary install
  python -m installer --destdir="$(pwd)/tmp" dist/*.whl
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  export PYTHONPATH="$(pwd)/tmp/$site_packages"
  export PATH="$(pwd)/tmp/usr/bin:$PATH"

  pytest -vv
}

package() {
  cd "$pkgname"

  python -m installer --destdir="$pkgdir" dist/*.whl
}
