# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor: Vianney le Clément <vleclement AT gmail·com>
# Contributor: Peter Simons <simons@cryp.to>

pkgbase=parallel
pkgname=(parallel parallel-docs)
pkgver=20260622
pkgrel=1
pkgdesc='A shell tool for executing jobs in parallel'
arch=(any)
url='https://www.gnu.org/software/parallel/'
license=(GPL-3.0-or-later)
makedepends=(
  git
  perl
  libreoffice-fresh
  graphviz
  jdk-openjdk
  perl-pod2pdf
  perl-pod-pom-view-restructured
  # pod2texi provided by texinfo in base-devel
)
source=(
  "$pkgname::git+https://https.git.savannah.gnu.org/git/parallel.git?signed#tag=${pkgver}"
  0001-Remove-citation-things.patch
)
sha512sums=('1d04c9a9d3b830a94e50155fcac8bfc056ef5aa00bc8f8460ce59d49b4ba124d581ec8a059acfbc9053f43c6cf7d6cc00a5964a7f17a0d5b05c7a39c8984f97e'
            '6e651e199896be8682f2adcf94a86e89feb2de5fa8870cf1d204fc154fc5a505df9d792810b12516e463bef9a859ad6a6bd5b25e44f30b0bb6ebb1433acac742')
b2sums=('e985d5fcfabc6450c8a791c855140559177d4bd2f88186c0d80cc5794c432f46ecf720bbba62cd0f61ae9d7b76efcd67fe3e48f46f4221f5d237a05f7aae92a0'
        'c5e58edec928ff0934215faa74de5dfd32967937774bf0468108c610bc420a8ed0926320ba541f7c531f001b7c385ce92e4806d2f74e955adbb974c505fd6970')
validpgpkeys=('CDA01A4208C4F74506107E7BD1AB451688888888')

prepare() {
  cd "$pkgbase"

  # remove citation warnings
  # https://en.opensuse.org/openSUSE:Packaging_guidelines#Donation_requests
  patch -p1 -i "$srcdir/0001-Remove-citation-things.patch"

  autoreconf -fiv
}

build() {
  cd "$pkgbase"

  ./configure --prefix=/usr

  make
}

package_parallel() {
  depends=(perl procps)
  optdepends=('parallel-docs: documentation')

  cd "$pkgbase"

  make DESTDIR="$pkgdir" install

  # split documentation out of main package
  mv "$pkgdir/usr/share/doc" docs
}

package_parallel-docs() {
  pkgdesc+=' (documentation)'

  cd "$pkgbase"

  install -vd "$pkgdir/usr/share/doc"
  mv -v docs/* "$pkgdir/usr/share/doc"
}
# vim:set ts=2 sw=2 et:
