# Maintainer: David Runge <dvzrv@archlinux.org>
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: Brett Cornwall <ainola@archlinux.org>
# Contributor: Evgeniy Alekseev <arcanis at archlinux dot org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Geoffroy Carrier <geoffroy@archlinux.org>
# Contributor: William Rea <sillywilly@gmail.com>
# Contributor: Robert Emil Berge <filoktetes@linuxophic.org>
# Contributor: Jonas Hahnfeld <hahnjo@hahnjo.de>

pkgname=lilypond
pkgver=2.26.0
pkgrel=1
pkgdesc="Music engraving program, devoted to producing the highest-quality sheet music possible"
arch=(x86_64 aarch64)
url="https://lilypond.org"
license=(GFDL-1.3 GPL-3.0-or-later OFL-1.1)
groups=(pro-audio)
depends=(fontconfig libfontconfig.so
         freetype2 libfreetype.so
         ghostscript
         glib2 libgobject-2.0.so
         glibc libglib-2.0.so
         gsfonts
         guile
         harfbuzz libharfbuzz.so
         libgcc libgcc_s.so
         libstdc++ libstdc++.so
         pango libpango-1.0.so libpangoft2-1.0.so
         )
makedepends=(dblatex
             fontforge
             imagemagick
             python
             rsync
             t1utils
             texinfo
             texlive-basic
             texlive-bin
             texlive-binextra
             texlive-fontutils
             texlive-langcyrillic
             texlive-metapost
             texlive-xetex
             zip)
optdepends=('python: for lilypond-book and other scripts'
            'tex-gyre-fonts: for extra fonts'
            'ttf-dejavu: for extra fonts')
source=("https://lilypond.org/downloads/sources/v${pkgver%.*}/$pkgname-$pkgver.tar.gz")
sha512sums=('94854f697093b764a9732dff85a822149846b25b0d2dc26008f3dd755674f77d18f4ff957bdf73c6837af434b009181acd108ab79c4581aedbbca210b633c516')
b2sums=('24a6074382a501b5549c4d1faf5305b9b409a4bc7de4aaaa02785d81df9d0781fc76edc0fe3ea9fc23d54d7e1e7a807680df75473cde50e66d7992884191f8a8')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
              --disable-texi2html
  make all bytecode
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" vimdir="/usr/share/vim/vimfiles" install install-bytecode
  install -vDm 644 LICENSE.OFL -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 {AUTHORS,NEWS}.txt README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
