# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>

pkgname=libva
pkgver=2.23.0
pkgrel=2
pkgdesc='Video Acceleration (VA) API for Linux'
arch=(x86_64 aarch64)
url=https://intel.github.io/libva/
license=(MIT)
depends=(
  glibc
  libdrm
  libgl
  libx11
  libxcb
  libxext
  libxfixes
  wayland
)
makedepends=(
  git
  libglvnd
  mesa
  meson
)
optdepends=(
  'intel-media-driver: backend for Intel GPUs (>= Broadwell)'
  'libva-intel-driver: backend for Intel GPUs (<= Haswell)'
  'libva-mesa-driver: backend for AMD and NVIDIA GPUs'
)
provides=(
  libva-drm.so
  libva-glx.so
  libva-wayland.so
  libva-x11.so
  libva.so
)
backup=(etc/libva.conf)
source=(git+https://github.com/intel/libva.git#tag=${pkgver})
b2sums=('010fa62fd2ee0b17678614bacacff0316a649e2305075bab76692d2d02634a76696bd0084184e4e07a61b65544882ee0b7b2e843fb69b6e1b156dc1d79b5679e')

build() {
  CFLAGS+=" -DENABLE_VA_MESSAGING" # Option missing
  arch-meson libva build
  meson compile -C build
}

package() {
  meson install -C build --destdir "${pkgdir}"
  install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
  install -Dm 644 /dev/stdin "${pkgdir}"/etc/libva.conf <<END
LIBVA_MESSAGING_LEVEL=1
END
}
