# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Gour <Gour <gour@mail.inet.hr>

pkgname=libisoburn
pkgver=1.5.8.2
_pkgver=$(echo $pkgver | sed -e 's/\.\([0-9]*.\)$/.pl0\1/')
pkgrel=1
pkgdesc='Frontend for libraries libburn & libisofs'
arch=(x86_64 aarch64)
url='https://dev.lovelyhq.com/libburnia/libisoburn'
license=(GPL-2.0-or-later)
depends=(
  glibc
  sh
  readline
  libburn
  libisofs
)
makedepends=(git)
optdepends=(
  'tk: for xorriso-tcltk frontend'
  'sudo: for use with xorriso-dd-target'
)
provides=(xorriso xorriso-tcltk)
source=("$pkgname::git+$url#tag=release-${_pkgver}")
sha512sums=('ffb7da76ba6e745c83905192304ac65417cc92e8a98a3a8df80871baebf2fd12d57c087383c92b8bbf4bdb91eaf5b576bdf3ef3306fee99d6cb6dc97a6e86382')
b2sums=('7f6e908ea529685992eb62bbb1ddb1588543fb0918163b374fb8ca984d45e4b5dd5fedbac11724c742c31aec7e64049e477d857159097c406186bc6b332569db')

prepare() {
  cd "$pkgname"

  autoreconf -vfi
}

build() {
  cd "$pkgname"

  ./configure \
    --prefix=/usr \
    --enable-year2038 \
    --disable-static

  make
}

package() {
  cd "$pkgname"

  make DESTDIR="$pkgdir" install
}
