# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Thorsten Töpper <atsutane-tu@freethoughts.de>
# Contributor: Carl Flippin <carlf@photocarl.org>

pkgbase=libdbi
pkgname=(
  libdbi
  libdbi-docs
)
pkgver=0.9.0
pkgrel=8
pkgdesc="Database independant abstraction layer for C"
arch=('x86_64' 'aarch64')
url="http://libdbi.sourceforge.net/"
license=('LGPL-2.1-or-later')
depends=('glibc')
options=(!emptydirs)
source=("https://downloads.sourceforge.net/$pkgbase/$pkgbase-$pkgver.tar.gz")
b2sums=('36ee5d9ec0a9b088735173cfa9a85e30ee595d6781aafeb994271e7745d259dbe983bea037182c471dc35ae36486a5fb8690e9c716e2e08a4a3964d90abd64f0')

prepare() {
  cd $pkgbase-$pkgver
  autoreconf -fiv
}

build() {
  cd $pkgbase-$pkgver
  ./configure --prefix=/usr
  make
}

package_libdbi() {
  cd $pkgbase-$pkgver
  make DESTDIR="$pkgdir" install
  make -C doc DESTDIR="$pkgdir" uninstall
}

package_libdbi-docs() {
  pkgdesc="Developer documentation for libdbi"
  depends=()

  cd $pkgbase-$pkgver
  make -C doc DESTDIR="$pkgdir" install
}
