# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Andrew Cook <ariscop@gmail.com>

pkgname=libbluray
pkgver=1.4.1
pkgrel=1
pkgdesc='Library to access Blu-Ray disks for video playback'
arch=(x86_64 aarch64)
url=https://www.videolan.org/developers/libbluray.html
license=(LGPL-2.1-only)
depends=(
  fontconfig
  glibc
  libfreetype.so
  libxml2
)
makedepends=(
  apache-ant
  git
  java-environment=17
  meson
  ninja
)
optdepends=('java-runtime: BD-J library')
provides=(libbluray.so)
_tag=7d94f2660af5bfc16015291a03539329135c18f1
source=(
  git+https://code.videolan.org/videolan/libbluray.git#tag=${_tag}
  git+https://code.videolan.org/videolan/libudfread.git
)
b2sums=('b59edf3c322a19fc9667f4646f9a2bd6ccb7400f2eb534e3946e14b6f37f579badc5594edcd76853ba17ff9793a890ce16bc07c0335d1d5e6ac3ab0e86177f11'
        'SKIP')

pkgver() {
  cd libbluray
  git describe --tags
}

prepare() {
  cd libbluray
  for submodule in contrib/libudfread; do
    git submodule init ${submodule}
    git config submodule.${submodule}.url ../${submodule#*/}
    git -c protocol.file.allow=always submodule update ${submodule}
  done
}

build() {
  arch-meson libbluray build
  meson compile -C build
}

package() {
  DESTDIR="${pkgdir}" meson install -C build
}

# vim: ts=2 sw=2 et:
