# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=invariant
pkgname=haskell-invariant
pkgver=0.6.5
pkgrel=10
pkgdesc="Haskell98 invariant functors"
url="https://github.com/nfrisby/invariant-functors"
license=('BSD-2-Clause')
arch=('x86_64' 'aarch64')
depends=('ghc-libs' 'haskell-bifunctors' 'haskell-comonad' 'haskell-contravariant'
         'haskell-profunctors' 'haskell-statevar' 'haskell-tagged' 'haskell-th-abstraction'
         'haskell-unordered-containers')
makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck')
source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
sha512sums=('ce1fba1ebb647580b9131078f6cca46ce00284e5b5a60bb6a28beac4da086600f621a0630bff9644fc6b718c6b3df2f18a2126c27750b2074c1c352b7143694d')

build() {
    cd $_hkgname-$pkgver
    
    runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
    runhaskell Setup build $MAKEFLAGS
    runhaskell Setup register --gen-script
    runhaskell Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
    cd $_hkgname-$pkgver
    runhaskell Setup test --show-details=direct
}

package() {
    cd $_hkgname-$pkgver
    
    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
    runhaskell Setup copy --destdir="$pkgdir"
    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
