# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Maintainer: Robin Candau <antiz@archlinux.org>
# Contributor: Christian Muehlhaeuser <muesli at gmail dot com>
# Contributor: Stephen Gregoratto <dev@sgregoratto.me>

pkgname=glow
pkgver=2.1.2
pkgrel=1
pkgdesc="Command-line markdown renderer"
url="https://github.com/charmbracelet/glow"
arch=('x86_64' 'aarch64')
license=('MIT')
depends=('glibc')
makedepends=('git' 'go')
options=('!lto')
source=("git+${url}.git#tag=v${pkgver}")
b2sums=('48cf420f30e87e0298912af9efe2cd1b761d9881a3895afc67da45dd5d560ec5cd1f669d1c5f6dd53e534ea11cecdabd21a7b9bf7248d518889b2bfd1fde81b5')

prepare() {
	cd "${pkgname}"

	mkdir -p build/
	go mod download
}

build() {
	cd "${pkgname}"

	export CGO_CPPFLAGS="${CPPFLAGS}"
	export CGO_CFLAGS="${CFLAGS}"
	export CGO_CXXFLAGS="${CXXFLAGS}"
	export CGO_LDFLAGS="${LDFLAGS}"
	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
	go build -v -ldflags "-X main.Version=${pkgver}" -o build .

	build/glow completion bash > completion.bash
	build/glow completion fish > completion.fish
	build/glow completion zsh > completion.zsh
}

package() {
	cd "${pkgname}"

	install -Dm 755 "build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"

	install -Dm 644 completion.bash "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
	install -Dm 644 completion.fish "${pkgdir}/usr/share/fish/vendor_completions.d/${pkgname}.fish"
	install -Dm 644 completion.zsh "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"

	install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -Dm 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}
