# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Baptiste Daroussin <baptiste.daroussin@gmail.com>
# Contributor: Grigorios Bouzakis <grbzks[at]gmail[dot]com>
# Contributor: mightyjaym <jm.ambrosino@free.fr>

pkgname=giflib
pkgver=6.1.3
pkgrel=1
pkgdesc='Library for reading and writing gif images'
arch=('x86_64' 'aarch64')
url='https://giflib.sourceforge.net/'
license=('MIT')
depends=('glibc')
makedepends=(
  'docbook-xml'
  'docbook-xsl'
  'git'
  'imagemagick'
  'xmlto'
)
provides=('libgif.so')
source=("${pkgname}::git+https://git.code.sf.net/p/giflib/code#tag=${pkgver}")
sha512sums=('8d2c425c9a5ae4f1ad00d302bf485148f67d7c29f6065e525c971808747a337015c34a79e331218300f601e256bc16ff68ccd051ebeb4a111a68a99d5c7a93d2')

build() {
  cd ${pkgname}
  CFLAGS="${CFLAGS/_FORTIFY_SOURCE=3/_FORTIFY_SOURCE=2}"
  make
}

check() {
  cd ${pkgname}
  make check
}

package() {
  cd ${pkgname}
  make PREFIX=/usr DESTDIR="${pkgdir}" install
  install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et:
