# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Hugo Doria <hugo@archlinux.org>
# Contributor: Sarah Hay <sarah@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>

pkgname=faac
pkgver=1.50
pkgrel=1
pkgdesc="Freeware Advanced Audio Coder"
arch=(x86_64 aarch64)
url="https://github.com/knik0/faac"
license=(
  GPL-2.0-or-later
  GPL-3.0-or-later
  LGPL-2.1-or-later
  LicenseRef-ISO-MPEG-4
)
depends=(glibc)
makedepends=(
  git
  meson
)
provides=(libfaac.so)
source=(
  $pkgname::git+$url#tag=$pkgname-$pkgver
)
sha512sums=('02b19be5642070e6c928365649deefe24f831fab357cc4e83af695c16ea072a8bc495acf66c732b6aa66b17d69fefd92789c181886b6226ac8fbcea97ef0e823')
b2sums=('c807a05c49c91cad7bf94687ab96acb91c5e7bf10ddbe572484b06a4be3a6a981cd7a315eb16a2be8030a753dc3d0942a93c8aa9587a65cb5461836d43e8f605')

prepare() {
  # extract custom license
  sed -n '9,37p' $pkgname/README > LicenseRef-ISO-MPEG-4.txt
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  meson test -C build
}

package() {
  meson install -C build --destdir "$pkgdir"
  install -vDm 644 $pkgname/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname/{AUTHORS,ChangeLog,NEWS,README,TODO} -t "$pkgdir/usr/share/doc/$pkgname/"
  install -vDm 644 LicenseRef-ISO-MPEG-4.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
}
