# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>

pkgname=cbindgen
pkgver=0.29.2
pkgrel=2
pkgdesc="A tool for generating C bindings to Rust code"
url="https://github.com/mozilla/cbindgen"
arch=(x86_64 aarch64)
license=(MPL-2.0)
depends=(
  glibc
  libgcc
)
makedepends=(
  cargo
  git
)
checkdepends=(
  cmake
  cython
  python
)
options=(!lto)
source=("git+$url#tag=v$pkgver")
b2sums=('35a8701948006c362f385c89da78aa2dac33007ac512232e743a0f4c7c3491b4e753200d11ab8738d9b207778c1b41c328aec0c2cf663ca0569778779be9ed45')

# Use debug
export CARGO_PROFILE_RELEASE_DEBUG=2 CARGO_PROFILE_RELEASE_STRIP=false

# Use LTO
export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1

prepare() {
  cd cbindgen
  cargo fetch --locked --target "$(rustc --print host-tuple)"
}

build() {
  cd cbindgen
  cargo build --release --frozen
}

check() {
  cd cbindgen
  # Tests need nightly features
  RUSTC_BOOTSTRAP=1 cargo test --frozen
}

package() {
  cd cbindgen
  install -Dt "$pkgdir/usr/bin" target/release/cbindgen
  install -Dt "$pkgdir/usr/share/doc/$pkgname" -m644 CHANGES \
    {README,docs,internals}.md
}

# vim:set sw=2 sts=-1 et:
