# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Kevin <kevin@archlinux.org>
# Contributor: criminy <criminy@gmail.com>

pkgbase=cairomm
pkgname=(
  cairomm
  cairomm-docs
)
pkgver=1.14.6
pkgrel=1
pkgdesc="C++ bindings for Cairo"
url="https://www.cairographics.org/cairomm/"
arch=(x86_64 aarch64)
license=(LGPL-2.0-or-later)
depends=(
  cairo
  glibc
  libgcc
  libsigc++
  libstdc++
)
makedepends=(
  git
  libsigc++-docs
  meson
  mm-common
)
options=(!emptydirs)
source=("git+https://gitlab.freedesktop.org/cairo/cairomm.git#tag=$pkgver")
b2sums=('2d87fa35ac313a5976ecaaacf486bceb68f59c69b91d41ac4592ea0b2ce980a8d3ab5863d7b721e08cec5ccae11bf0bd3926e9326ee33d6d6e874c7823181652')

prepare() {
  cd cairomm
}

build() {
  local meson_options=(
    -D maintainer-mode=true
  )

  arch-meson cairomm build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package_cairomm() {
  depends+=(libsigc-2.0.so)
  provides=(libcairomm-1.0.so)

  meson install -C build --destdir "$pkgdir"

  # Split -docs
  mkdir -p docs/usr/share
  mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
}

package_cairomm-docs() {
  pkgdesc+=" (documentation)"
  depends=()
  options=(!strip)

  mv -t "$pkgdir" docs/*
}

# vim:set sw=2 sts=-1 et:
