# Maintainer: Anatol Pomozov
# Maintainer: Carl Smedstad <carsme@archlinux.org>
# Contributor: Tommaso Sardelli <lacapannadelloziotom at gmail dot com>

pkgname=bpftrace
pkgver=0.26.1
pkgrel=1
pkgdesc='High-level tracing language for Linux eBPF'
arch=('x86_64' 'aarch64')
url='https://github.com/iovisor/bpftrace'
license=('Apache-2.0')
depends=(
  'bcc'
  'clang'
  'glibc'
  'libelf'
  'libgcc'
  'libpcap'
  'libstdc++'
  'llvm-libs'
  'systemd-libs'
  'zip'
  'zlib'
  'zstd'
)
makedepends=(
  'asciidoctor'
  'binutils'
  'bpf'
  'cereal'
  'cmake'
  'git'
  'gtest'
  'linux-headers'
  'llvm'
  'xxd'
)
options=(
  '!debug'
  '!strip'
)
source=(
  "git+$url.git#tag=v$pkgver"
  "$pkgname-libbpf::git+https://github.com/libbpf/libbpf.git"
)
b2sums=('416db7329d5274923133499bc2463b2759686bad6d201d1d13f1d33be394ec6ee1f93703efeed4f919b7bd86e89e3e78c773bb785a2c2f615e1c5168ca33dfa3'
        'SKIP')

prepare() {
  cd $pkgname
  git submodule init
  git config submodule.libbpf.url ../$pkgname-libbpf
  git -c protocol.file.allow=always submodule update libbpf
}

build() {
  cmake -S $pkgname -B build \
    -D CMAKE_BUILD_TYPE=None \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -W no-dev \
    -D ENABLE_SYSTEMD=ON
  cmake --build build
}

check() {
  ctest --test-dir build --output-on-failure
}

package() {
  depends+=(
    'binutils' 'libsframe.so'
  )

  DESTDIR="$pkgdir" cmake --install build
}
