# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>

pkgbase=atkmm
pkgname=(
  atkmm
  atkmm-docs
)
pkgver=2.28.5
pkgrel=1
pkgdesc="C++ bindings for ATK"
url="https://www.gtkmm.org/"
arch=(x86_64 aarch64)
license=(LGPL-2.1-or-later)
depends=(
  atk
  glib2
  glibc
  glibmm
  libgcc
  libstdc++
)
makedepends=(
  git
  glibmm-docs
  meson
  mm-common
)
options=(!emptydirs)
source=("git+https://gitlab.gnome.org/GNOME/atkmm.git#tag=$pkgver")
b2sums=('c69c631bf79ffa6b78e6809bac8e95da572db57a78b3eef606a8b7aa113744934947236161c0044039bf4d1c27ec2686ca1c70019d8c9175dde0cf1df50f70f1')

prepare() {
  cd atkmm
}

build() {
  local meson_options=(
    -D maintainer-mode=true
  )

  arch-meson atkmm build "${meson_options[@]}"
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package_atkmm() {
  depends+=(
    libglibmm-2.4.so
    libsigc-2.0.so
  )
  provides=(libatkmm-1.6.so)

  meson install -C build --destdir "$pkgdir"

  # Split -docs
  mkdir -p docs/usr/share
  mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
}

package_atkmm-docs() {
  pkgdesc+=" (documentation)"
  depends=()
  options=(!strip)

  mv -t "$pkgdir" docs/*
}

# vim:set sw=2 sts=-1 et:
