# Maintainer:
# Contributor: Felix Yan <felixonmars@archlinux.org>

pkgname=python-manuel
_name="${pkgname#python-}"
pkgver=1.13.0
pkgrel=1
pkgdesc="Manuel lets you build tested documentation"
arch=(any)
license=(Apache-2.0)
url="https://github.com/benji-york/manuel"
depends=(
  python
)
makedepends=(
  git
  python-build
  python-installer
  python-setuptools
  python-wheel
)
checkdepends=(python-zope-testing)
source=(
  git+https://github.com/benji-york/manuel.git#tag=$pkgver
)
sha512sums=('9f74c48549ad6e4ac7cda0fa4bb5572c125f9f9ad7a6db57b44c9852cd9b59c19ad957997d8c56c0a9a603675b19e25fbecac3fbc8ff8c4d1b3387f4424d5db4')
b2sums=('0d5538458b5e11da40ea2b3a9685afe374c1aa8c1d304bbdc23eb15b6e983ead6aa57bc6320e669763e57e2a0bd41b4f8be035b47d05422edeef962de8cfd5a0')

prepare() {
  cd $_name

  # setuptools not needed: https://github.com/benji-york/manuel/issues/36
  sed -e "/'setuptools',/d" -i setup.py
}

build() {
  cd $_name
  python -m build --wheel --no-isolation
}

check() {
  cd $_name
  PYTHONPATH="$PWD/src" python -m unittest -vv $_name.tests.test_suite
}

package() {
  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  cd $_name
  python -m installer --destdir="$pkgdir" dist/*.whl

  rm -frv "$pkgdir/$site_packages/$_name/"tests.py
}
