# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>

pkgname=libexttextcat
pkgver=3.4.8
pkgrel=1
pkgdesc="N-Gram-Based Text Categorization library primarily intended for language guessing"
arch=('x86_64' 'aarch64')
url="https://wiki.documentfoundation.org/Libexttextcat"
license=('BSD-3-Clause')
depends=('glibc')
provides=('libtextcat')
# options=(!lto)
source=(#https://dev-www.libreoffice.org/src/$pkgname/$pkgname-$pkgver.tar.xz
        https://dev-www.libreoffice.org/src/$pkgname-$pkgver.tar.xz
        Fix-type-mismatch-between-declaration-and-definition.patch)
sha256sums=('93eb89fd4fc8f565806354e100e778b3ac9a24e5fc04c24e6a83fb1e9b6c9d59'
            '35b39e2e84aff6e2856e527c1fdbe08a75fa9266c2495fde7c4409c3464a84df')
            
prepare() {
  cd "${srcdir}"/$pkgname-$pkgver
  patch -Np1 -i ../Fix-type-mismatch-between-declaration-and-definition.patch
}

build() {
  cd "${srcdir}"/$pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}"/$pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/$pkgname/LICENSE
}
