# Maintainer: Morten Linderud <foxboron@archlinux.org>
# Contributor: Cody P Schafer <archlinux@codyps.com>
# Contributor: John Eivind Helset <jehelset@gmail.com>

pkgname=debugedit
pkgver=5.3
pkgrel=1
pkgdesc='Tool to mangle source locations in .debug files'
arch=('x86_64' 'aarch64')
url='https://sourceware.org/debugedit/'
license=('GPL-3.0-or-later' 'GPL-2.0-or-later' 'LGPL-2.0-or-later')
depends=('glibc' 'libelf' 'xxhash' 'cpio' 'elfutils' 'gdb')
makedepends=('help2man')
source=("https://sourceware.org/ftp/debugedit/${pkgver}/debugedit-${pkgver}.tar.xz"{,.sig}
        "remove-dwz.patch")
validpgpkeys=(
    '28FF4B30A88D5523A7E2CBA20376A15C6FFC11CD' # Mark J. Wielaard <mark@klomp.org>
)
sha512sums=('a02e04f5b91e0ec5d880207658e5b89b28424ffee6aed7374c495c0c49b2f0180eeb2277bdb758a3d245279a2083d5f7b8b4872b8972b92d5c92ef5f1d27d958'
            'SKIP'
            'fe10d161fffd392d8ac86d439eaac267955a81ca2bb68d4218aa585fab6ca07b9ecb12f146050077bf82f95d1c93cbf6e916eec5713efb729f26f53b74677b15')

prepare() {
    cd "debugedit-${pkgver}"
    patch -Np1 < "$srcdir/remove-dwz.patch"
    autoreconf -fiv
}

build() {
    cd "debugedit-${pkgver}"
    ./configure --prefix=/usr
    make
}

package() {
    cd "debugedit-${pkgver}"
    make DESTDIR="${pkgdir}" install
}
