# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>

_gemname='process-metrics'
pkgname="ruby-${_gemname}"
pkgver=0.11.1
pkgrel=1
pkgdesc='Provide detailed OS-specific process metrics'
arch=('any')
url='https://github.com/socketry/process-metrics'
license=('MIT')
depends=(
  procps-ng
  ruby
  ruby-console
  ruby-samovar
)
makedepends=(
  ruby-rdoc
)
checkdepends=(
  ruby-bake
  ruby-bake-test
  ruby-bake-test-external
  ruby-bundler
  ruby-covered
  ruby-decode
  ruby-sus
)
options=('!emptydirs')
source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('f5363b17407c42117bd9d4e879e1c0f63dc2ff475570d8749650cefd76f5d648896affd3502b03173ba4ae94a05809e0235244d7fca0d58a502c026a23191e7e')
b2sums=('fa9006ba32ad5f42264d8913f6bc486d08d8291aa31a06a9f3811cc05c0901b63fec9ea9b8c6e99ffad42d4cc39cb8a1745820302058cfc703fa2ed6fb5d2098')

prepare() {
  cd "${_gemname}-${pkgver}"

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed --in-place --regexp-extended \
    --expression 's|~>|>=|g' \
    --expression '/signing_key/d' \
    "${_gemname}.gemspec"

  sed --in-place \
    --expression '/group :maintenance/,/end/d' \
    --expression '/rubocop/d' \
    gems.rb
}

build() {
  cd "${_gemname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  gem build --verbose "${_gemname}.gemspec"

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --build-root "tmp_install" \
    "${_gemname}-${pkgver}.gem"
}

check() {
  cd "${_gemname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install${_gemdir}" bake test
}

package() {
  cd "${_gemname}-${pkgver}"

  cp --archive --verbose tmp_install/* "${pkgdir}"

  install --verbose -D --mode=0644 license* --target-directory "${pkgdir}/usr/share/licenses/${pkgname}"
  install --verbose -D --mode=0644 *.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}

# vim: tabstop=2 shiftwidth=2 expandtab:
