# Maintainer: David Runge <dvzrv@archlinux.org>

pkgname=libopenmpt
pkgver=0.8.6
pkgrel=1
pkgdesc="A library to render tracker music to a PCM audio stream"
arch=(x86_64 aarch64)
url="https://lib.openmpt.org/libopenmpt/"
license=(BSD-3-Clause)
depends=(
  flac
  glibc
  libgcc
  libogg  # required by pkgconf
  libpulse
  libsndfile
  libstdc++
  libvorbis
  mpg123
  portaudio
  zlib
)
makedepends=(
  autoconf-archive
  doxygen
  help2man
)
provides=(libopenmpt.so)
source=($pkgname-$pkgver.tar.gz::https://lib.openmpt.org/files/libopenmpt/src/$pkgname-$pkgver+release.autotools.tar.gz)
sha512sums=('a9c813f80d2a688d52b161996ff7efab4a7d954ba177e2d2b3541bd9e7e246019510ea4f9027cbcb4e8ef50a21e633aa5fbe796435392e37383900b320fca03f')
b2sums=('44e326d8f8da088cd0353926c80726de6b81b428c79157785c7bb80ebc26d812c08e2463df12d8624a5d1430677cd0b502988ee3b9974b61a72497e9f53ba14a')

prepare() {
  cd $pkgname-$pkgver+release.autotools
  autoreconf -fiv
}

build() {
  cd $pkgname-$pkgver+release.autotools
  ./configure --prefix=/usr
  # prevent excessive overlinking due to libtool
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  make -k check -C $pkgname-$pkgver+release.autotools
}

package() {
  cd $pkgname-$pkgver+release.autotools
  make DESTDIR="$pkgdir" install
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
