# Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Maxim Baz <archlinux at maximbaz dot com>

pkgname=fd
pkgver=10.4.2
pkgrel=2
pkgdesc='Simple, fast and user-friendly alternative to find'
arch=('x86_64' 'aarch64')
url=https://github.com/sharkdp/fd
license=('MIT' 'Apache-2.0')
depends=('glibc' 'jemalloc' 'libgcc')
makedepends=('rust')
source=("fd-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('115a2563ee4e80910c74d18a78a9fefcde2d530e6598ee03265e28e95685055e34d2a974d85aa2a173e8f104730a95ec87bcc86bbbe65ced80a903def169fe2d')

prepare() {
  cd fd-$pkgver
  cargo fetch --locked --target "$(rustc --print host-tuple)"
}

build() {
  cd fd-$pkgver
  export JEMALLOC_OVERRIDE=/usr/lib/libjemalloc.so
  export CARGO_FEATURE_UNPREFIXED_MALLOC_ON_SUPPORTED_PLATFORMS=1
  cargo build --release --locked --offline
}

check() {
  cd fd-$pkgver
  export JEMALLOC_OVERRIDE=/usr/lib/libjemalloc.so
  export CARGO_FEATURE_UNPREFIXED_MALLOC_ON_SUPPORTED_PLATFORMS=1
  cargo test --locked --offline
}

package() {
  cd fd-$pkgver
  install -Dm755 target/release/fd "$pkgdir"/usr/bin/fd

  make completions
  install -Dm644 autocomplete/fd.bash "$pkgdir"/usr/share/bash-completion/completions/fd
  install -Dm644 autocomplete/fd.fish "$pkgdir"/usr/share/fish/vendor_completions.d/fd.fish
  install -Dm644 autocomplete/_fd "$pkgdir"/usr/share/zsh/site-functions/_fd

  install -Dm644 doc/fd.1 "$pkgdir"/usr/share/man/man1/fd.1
  install -Dm644 LICENSE-MIT "$pkgdir"/usr/share/licenses/fd/LICENSE-MIT
}

# vim:set ts=2 sw=2 et:
