# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>

pkgbase=bubblewrap
pkgname=(
  bubblewrap
  bubblewrap-suid
)
pkgver=0.11.2
pkgrel=1
pkgdesc='Unprivileged sandboxing tool'
url='https://github.com/containers/bubblewrap'
arch=(x86_64 aarch64)
license=(LGPL-2.0-or-later)
depends=(
  glibc
  libcap
  libgcc
)
makedepends=(
  bash-completion
  docbook-xsl
  git
  libxslt
  meson
)
source=("git+$url?signed#tag=v$pkgver")
b2sums=('7166c1483c8c8d6b2fed4220f023b51bc0de2ccc2c61a3435e1adc0d1ded316de027721a6c71e14c957e65f81bf0195634b39db834071055aaff4484ad2d0ecc')
validpgpkeys=(
  DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90 # Simon McVittie <smcv@collabora.com>
  252C6FEA78A69D3BC0AD458A616C5BDC0C29AB04 # Alexander Larsson <alexl@redhat.com>
)

prepare() {
  cd $pkgbase
}

build() {
  local meson_options=(
    -D selinux=disabled
  )

  arch-meson $pkgbase build "${meson_options[@]}"
  arch-meson $pkgbase build-suid "${meson_options[@]}" -D support_setuid=true

  meson compile -C build
  meson compile -C build-suid
}

check() {
  # Broken in our containers
  meson test -C build --print-errorlogs || :
  meson test -C build-suid --print-errorlogs || :
}

package_bubblewrap() {
  meson install -C build --destdir "$pkgdir"
}

package_bubblewrap-suid() {
  pkgdesc+=" (setuid variant)"
  provides=("bubblewrap=$pkgver-$pkgrel")
  conflicts=(bubblewrap)

  meson install -C build-suid --destdir "$pkgdir"
  chmod u+s "$pkgdir/usr/bin/bwrap"
}

# vim:set sw=2 sts=-1 et:
