# Maintainer: David Runge <dvzrv@archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Hugo Doria <hugo@archlinux.org>
# Contributor: Sarah Hay <sarah@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>

pkgname=faac
pkgver=1.40
pkgrel=1
pkgdesc="Freeware Advanced Audio Coder"
arch=(x86_64 aarch64)
url="https://github.com/knik0/faac"
license=(
  GPL-2.0-or-later
  GPL-3.0-or-later
  LGPL-2.1-or-later
  LicenseRef-ISO-MPEG-4
)
depends=(glibc)
makedepends=(
  git
  meson
)
provides=(libfaac.so)
source=(
  $pkgname::git+$url#tag=$pkgname-$pkgver
)
sha512sums=('06e541fc5ba47989593333faafb52462e10b569c73e0945fcf5046b6ad2289cc9cad3907775740eb97b58259537cef1e420aee31d89130ffae16878940afa771')
b2sums=('6662f52de8b4b9182998a75b75852323b4f91e25851737be4aaa2ca4967beffccdb690429237f7d1cb514cbd34d602dc8939f3fd2ba8ffa8c7cfcf2ea36d51d9')

prepare() {
  # extract custom license
  sed -n '9,37p' $pkgname/README > LicenseRef-ISO-MPEG-4.txt
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  meson test -C build
}

package() {
  meson install -C build --destdir "$pkgdir"
  install -vDm 644 $pkgname/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -vDm 644 $pkgname/{AUTHORS,ChangeLog,NEWS,README,TODO} -t "$pkgdir/usr/share/doc/$pkgname/"
  install -vDm 644 LicenseRef-ISO-MPEG-4.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
}
