# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Maintainer: Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kate
pkgver=26.04.2
pkgrel=2
arch=(x86_64)
license=(GPL-2.0-or-later LGPL-2.0-or-later)
pkgdesc='Advanced text editor'
groups=(kde-applications
        kde-utilities)
url='https://apps.kde.org/kate/'
depends=(glibc
         #gpgmepp
         karchive
         kbookmarks
         kcolorscheme
         kcompletion
         kconfig
         kconfigwidgets
         kcoreaddons
         kcrash
         kdbusaddons
         kguiaddons
         ki18n
         kiconthemes
         kio
         knewstuff
         kparts
         kservice
         ktexteditor
         kuserfeedback
         kwidgetsaddons
         kwindowsystem
         kxmlgui
         #libstdc++
         qt6-base
         sh
         syntax-highlighting)
optdepends=('clang: C and C++ LSP support'
            'git: git-blame plugin' 
            'konsole: open a terminal in Kate'
            'python-lsp-server: Python LSP support'
            'qt6-declarative: RBQL plugin'
            'qtkeychain-qt6: SQL plugin'
            'rust: Rust LSP support'
            'texlab: LaTeX LSP support')
makedepends=(extra-cmake-modules
             kdoctools
             qtkeychain-qt6)
conflicts=(kwrite)
provides=(kwrite)
replaces=(kwrite)
source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
sha256sums=('f138a5b022b6ca0562b903bea7b2a794bb6bb18b88a9277ffcaf418b9b49018d'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}
